SQL Server ASP.NET C# Kitabı

Olaylar(Events)

Olaylar, mouse ile tıklama, klavyeden tuşa basma gibi kullanıcının işletim sistemi üzerinden gerçekleştirdiği faaliyetlerdir. Bu şekilde, uygulamamız içerisinde meydana gelen durum değişikliklerine karşı hassas olan ve bu değişiklikler doğrultusunda yönlendirilebilen programlama modeline olay güdümlü programlama (event driven programming) denir. Bu modeldeki programlar, bir şeyler yapmak için bazı şeylerin gerçekleşmesini beklerler. Bir bileşen üzerinde meydana gelen olayların takipçisi olup onları yakalayan mekanizmaya olay yöneticisi (event handler) denir. Olay tutucusu veya işleyicisi olarak ta tanımlanan event handler, ilgili olay gerçekleştiği zaman tetiklenir. Olay yöneticilerinin yönlendirilmesi bizim tarafımızda kodlanır, olay yöneticisinin olay gerçekleştikten sonra hangi işlemleri yapacağını delegatelerle tanımlarız. Yani olay yöneticileri, delegatelerle temsil edilir.

Eventleri aktif olarak Windows programlamada control’ler için kullanırız. ÖrneÄŸin kullanıcının mouse ile tıklaması Click event’inin, klavyede tuÅŸa basması KeyPress event’inin oluÅŸmasına neden olur. Bize düşen, Click, KeyPress gibi event’lerin altını doldurmaktır yani bu eventleri delegate aracılığıyla metodlarla iliÅŸkilendirmektir.

Bu bölümde derleme zamanında olay yönetimini ve çalışma zamanında olay yönetimini(dinamik olay yönetimi) işleyeceğiz.

VB.NET Eventleri iki farklı yöntemle tanımlayabiliriz. Ä°lk yöntem, bir delegate oluÅŸturmak ve event’i bu delegate türünden tanımlamaktır. Ä°kinci yöntem ise delegate tanımlamadan doÄŸrudan event’i, formatıyla birlikte tanımlamaktır. Bu yöntem delegate kullanılmadığı anlamına gelez çünkü derleyici bu durumda da event için bir delegate yaratır.

C# Bir eventi tanımlamadan önce o event’i temsil edecek delegate’in tanımlanması gerekir.

Yeni bir event oluÅŸturmak için “event” sözcüğü kullanılır. OluÅŸturulan eventleri tetiklemek için VB.NET’te RaiseEvent sözcüğü kullanılırken C# tarafında event’in ismi kullanılır.

'Eventin türünü belirleyen delegate
Public Delegate Sub ClickEventHandler(ByVal Mesaj As String)

Public Class CustomControl
    'Bu Class için bir event tanımlayalım.
    Public Event Click As ClickEventHandler
    'Public Event Click(ByVal Mesaj As String)

    'Click eventini tetikleyecek metod (Event raising method)
    Sub OnClick(ByVal Mesaj As String)
        RaiseEvent Click(Mesaj)
    End Sub
End Class

//Eventin türünü belirleyen delegate
public delegate void ClickEventHandler(string Mesaj);

class CustomControl
{
    //Bu Class için bir event tanımlayalım.
    public event ClickEventHandler Click;

    //Click eventini tetikleyecek metod (Event raising method)
    public void OnClick(string Mesaj)
    {
        Click(Mesaj);
    }//OnClick

}//CustomControl

DoÄŸru ÅŸartlar gerçekleÅŸtikten sonra event tetiklenir ve baÄŸlı olduÄŸu metodları çalıştırır. Bu metodlara Event Handler denilir. Event handling iÅŸlemini dinamik olarak çalışma zamanında yeniden implemente edebiliriz. Çalışma zamanında bir eventi bir metoda baÄŸlamak için (hooking) VB.Net’te AddHandler sözcüğü, C#’ta ise += operatörü kullanılır. Evente eklenmiÅŸ metodu kaldırmak için de (unhooking) VB.Net’te RemoveHandler sözcüğü, C#’ta da -= operatörü kullanılır. Burada dikkat edilmesi gereken konu, eventin baÄŸlanacağı metodların signature’leri event’in türü olan delegate ile aynı olmalıdır.

Module EventOrnek
    Sub Main()
        Dim o1 As New CustomControl
        AddHandler o1.Click, AddressOf MesajYaz
        AddHandler o1.Click, AddressOf MesajBuyukYaz

        'eventin çalışmasına sebep olan işlem
        o1.OnClick("Tatlı dil, her kapıyı açan sihirli bir anahtardır.")
        Console.WriteLine()

        'MesajYaz metodunu listeden çıkarıyoruz.
        RemoveHandler o1.Click, AddressOf MesajYaz
        o1.OnClick("Erdem , iyiyi elde etme gücüdür.")

        Console.ReadLine()
    End Sub

    Sub MesajYaz(ByVal Mesaj As String)
        Console.WriteLine(Mesaj)
    End Sub

    Sub MesajBuyukYaz(ByVal Mesaj As String)
        Console.WriteLine(Mesaj.ToUpper)
    End Sub

End Module

class Class1
{
    static void Main()
    {
        CustomControl o1 = new CustomControl();
        o1.Click += new ClickEventHandler(MesajYaz);
        o1.Click += new ClickEventHandler(MesajBuyukYaz);

        //eventin çalışmasına sebep olan işlem
        o1.OnClick("Tatlı dil, her kapıyı açan sihirli bir anahtardır.");
        Console.WriteLine();

        //MesajYaz metodunu listeden çıkarıyoruz.
        o1.Click -= new ClickEventHandler(MesajYaz);
        o1.OnClick("Erdem , iyiyi elde etme gücüdür.");

        Console.ReadLine();
    }

    static void MesajYaz(string Mesaj)
    {
        Console.WriteLine(Mesaj);
    }

    static void MesajBuyukYaz(string Mesaj)
    {
        Console.WriteLine(Mesaj.ToUpper());
    }

}//Class1

Tatlı dil, her kapıyı açan sihirli bir anahtardır.
TATLI DİL, HER KAPIYI AÇAN SİHİRLİ BİR ANAHTARDIR.

ERDEM , Ä°YÄ°YÄ° ELDE ETME GÃœCÃœDÃœR.

Örnekte gerçek bir kontrol olmadığı için event’i OnClick ile tetikliyoruz. Görüldüğü gibi birbirleriyle konuÅŸacak yapıların signatureleri aynı biçime sahip. ÖrneÄŸin bir metodu windows uygulamasında bir butonun click eventine baÄŸlamak için metodun signature’i butonun click eventi ile aynı olmalıdır. Butonların click eventinin formatı ÅŸu ÅŸekildedir;

Public Event Click As EventHandler

Public Delegate Sub EventHandler(ByVal sender As Object, ByVal e As EventArgs)

public event EventHandler Click;

public delegate void EventHandler(object sender, EventArgs e);

Metadata kodlarından görüldüğü gibi kontrollerin click event’i System.EventHandler isimli delegate türüne sahiptir. Dolayısıyla çalışacak metod da ÅŸu ÅŸekilde tanımlanmalıdır.

AddHandler Button1.Click, AddressOf Metod

Sub Metod(ByVal sender As System.Object, ByVal e As System.EventArgs)
    'Ä°ÅŸlemler
End Sub

button1.Click += new EventHandler(Metod);

void Metod(object sender, System.EventArgs e){
	//Ä°ÅŸlemler
}

Bunlara ek olarak VB.Net’te eventleri yakalamanın kolay bir yolu da WithEvents ve Handles ikilisini kullanmaktır. Bu sözcükler daha çok Windows GUI (Graphical User Interface-Grafik Ara Birimi) uygulamalarında programlama, derleme zamanında metodları iliÅŸkilendirmek için kullanılır. WithEvents ifadesi, derleyiciye yaratılan nesnenin eventleriyle birlikte kullanılacağını ifade eder. Handles ifadesini kullanmak için nesneleri WithEvents ile tanımlamalıyız. AÅŸağıdaki örnekte bu ifadelerin kullanımı gösterilmiÅŸtir.

Friend WithEvents o1 As New CustomControl

Sub Main()
    o1.OnClick("Erdem , iyiyi elde etme gücüdür.")
    Console.ReadLine()
End Sub

'Handles sözcüğü ile MesajYaz metodu, o1 nesnesinin Click eventine bağlanmıştır.
Sub MesajYaz(ByVal Mesaj As String) Handles o1.Click
    Console.WriteLine(Mesaj)
End Sub

Handles ifadesiyle birden fazla event’i aynı metoda baÄŸlayabiliriz. Bunun için event’leri virgül ile ayırmamız yeterli olacaktır.

Friend WithEvents o1 As New CustomControl
Friend WithEvents o2 As New CustomControl

Sub Main()
    o1.OnClick("Erdem , iyiyi elde etme gücüdür.")
    o2.OnClick("Erdem , iyiyi elde etme gücüdür.")
End Sub

Sub MesajYaz(ByVal Mesaj As String) Handles o1.Click, o2.Click
    Console.WriteLine(Mesaj)
End Sub